How long do solar cells live? (part 3)

Finally, after much tinkering, I’ve got a system that’s worth committing to a PCB. Here is a shot of the prototype system being tested out…

A prototype breadboard lifetester being tested. Two solar cells are being held at MPP at the same time under the work-lamp. The arduino boards are used for PC interfacing and programming.

Above is a picture that I took as I was working on the system. At this point, two solar cells (under the work lamp) are illuminated and being driven at maximum power point (MPP) at the same time. As described previously, I used a current sensing circuit based on an inverting amplifier which is assembled on the long breadboard in the middle along with the DACs and ADCs needed to drive the circuit and collect data. On the neighbouring breadboard is a programmed ATMega328 chip which drives this process and is interfaced by I2C as a slave to another master ATMega328 on an Arduino UNO board. I needed another Arduino UNO board for programming the ATMega and for USB-Serial communication debugging when needed. There’s a neat article on this on the Arduino site here. Have a look at this schematic below for more detail of what I did exactly…

Schematic showing the layout of microcontroller and Arduino boards used in the picture above. Note that the analog circuit and SPI devices aren’t shown.

Unfortunately, the analog circuit that I was using was not quite doing the job. I noticed that although the output voltage from the DAC was as expected from the binary code that I was feeding into it, at the other end of the buffer amplifier (at the DUT terminal) it wasn’t. In particular, at Vin = 0V (short-circuit), the applied bias wasn’t 0V. It turns out that the buffer amplifier needs to work as a current sink in this case – current actually flows from ground to the buffer. To overcome this, in addition to +5V and 0V,  I also needed to supply -5V to the op-amp. To make sure that the output from the amplifier to the ADC, Vout, never went below 0V I used a precision rectifier circuit – it acts like an ideal diode; there’s no voltage drop at the output which is commonly associated with a regular diode. The simplified schematic is below and a full Fritzing file here.

Analog current sensing circuit used to drive the solar cells under test (DUT). The circuit is based on a precision rectifier/inverting amplifier. The range can be altered by changing Rsense.

Here’s what it does again in brief:

  1. Under illumination, current flows from ground to the buffer amplifier.
  2. Current flowing from ground to the buffer amplifier leads to a small (0 > Vx > -10mV) negative voltage across the sense resistor.
  3. This voltage is fed into an inverting op-amp. It is inverted and amplified 350 times. A precision rectifier arrangement ensures that the output can never go below 0V. Gain and offset can be tuned by means of trimmer resistors.
  4. The output is connected to an ADC for data logging and MPP tracking.

Below is some of the data that came out of this system…

Data measured from the prototype breadboard lifetime tester: live MPPT vs time (top panel) and the solar cell IV characteristic measured at the end of the test (bottom panel). Note that the MPP (DACx = 760) agrees well with the DAC setting during tracking.

The live MPPT data shows some fluctuation in voltage. Because of the hill climbing, perturb and observe algorithm used, the voltage is constantly being probed. You can also see a sharp step in the MPP data where I adjusted light intensity which is indicated by the increase in ADCx (current). Shortly afterwards (measurements are taken roughly every second), this is followed by DACx (applied voltage) as the MPPT system catches up which is expected. As a double check, I reset the lifetime tester to run another IV characteristic without changing the light intensity. This registered an MPP at DACx = 760 (0.38V) which was consistent with the MPP tracking data.

Having convinced myself that this system was working nicely, I decided it was time to design a PCB. More on that to come.

A solar simulator on a budget

Light source

To get the high light intensities that I needed for this project, I hunted around for a high-performance high colour temperature white LED and came up with this one. It’s a Cree XLamp CXA2520 high lumen output and efficacy LED array. I chose the 5000K version as I wanted something that would be closer to sunlight. The device delivers 2500Lm white light at 36V and draws 0.5A. I liked the fact that it was a chip-on-board assembly that was ready to mount. I tried a smaller device but cracked it when I tried to mount it on a heatsink.

Heat considerations

We really need a heatsink here because, even though LEDs are efficient, there is still quite a lot of heat to get rid of – 20W if we assume that all electrical power is converted to heat (obviously this is the worst case scenario given that a significant amount of power should be converted into light and radiated away*). Keeping the temperature down increases the efficiency of the system and the lifetime of the LED. More importantly, we don’t want to alter the environment around our solar cell too much as this would bring in an uncontrolled variable.

I found a CPU fan/heatsink laying around and looked into bonding it using adhesive thermal tape. Assuming the thermal resistance of the fan/heatsink is 0.4K/W, and that the ambient temperature is 20C, then the heatsink will run at 28C – hopefully, the LED will be in equilibrium with this so will also be at the same temperature. I checked the specs of the heat transfer adhesive and it seems its performance is predicted to be really good. To be able to transfer 20W heat power, it would need a temperature difference of only 0.001mK across it – so the LED would be at pretty much the same temperature as the heatsink surface we can assume.

Cree XLamp CXA2520 mounted on a CPU heatsink/fan under operation at very low current. Note that the masking tape shown here was removed for final testing.

Power output

This is the most important part: the power output calculation. We need to know how much light the LED actually is going to deliver to our solar cell – in the lifetime tester application, I envisage that each solar cell under test will be assigned its own LED and this way the system would be truly modular.

On to the calculations then…What we want to know is the light intensity (irradiance) on the solar cell front surface which is simply the light power per unit area. For instance, 1 Sun illumination has an intensity equal to 1kW/m2 which is itself a unit of irradiance. Here’s how we work this out:

  • The thing is we want to know how much “real” power the LED emits in Watts. Basically, our eyes are setup to be sensitive to some wavelengths over others (the peak of the eye response happens to be tuned to the sun’s peak emission per nm which is green light at around 500nm – let’s not get drawn into a discussion about evolution here). Measuring the light output in Lumens tells us how bright the LED will be to our eyes but doesn’t tell us how much power there actually is. We need to convert units and to do this, we need to know what colour the light is. If you remember, I said that our eyes have a peak sensitivity to green light. So green light has the most number of Lumens per Watt, 683 Lm/W. Other wavelengths have less. This Lm/W number is referred to as luminous efficacy of radiation – it relates luminous to radiative flux and tells us...for a given amount of light energy, how much does this stimulate our eyes. Weird huh. Don’t get this confused with luminous efficacy of the source which is a measure of the overall efficiency of the LED in converting Watts of electrical input into Lumens of emitted light (126 Lm/W in this case). In fact, increasing luminous efficacy is one way to increase the LEDs apparent efficiency; if we made it green, it would be about twice as efficient.
  • But we don’t have a green monochromatic light source, we have a white light source? So we need to average the contribution from all the different wavelengths that make up the emitted spectrum from the LED. This gets a bit complicated. Fortunately, we can make some assumptions. Let’s assume that the spectrum of the LED approximates a blackbody that has been truncated to the visible region (normally a blackbody emitter would radiate light in the NIR and UV that we can’t see so the luminous efficacy would be much lower overall). So the luminous efficacy of radiation will be 350 Lm/W. From this, we know the total radiant power output from the LED will be 2500 / 350 = 7.1 W. We’re getting there.
  • The total radiant power is helpful but we need to know about intensity, or the number of Watts emitted over a given area. One way to go would be to assume that it’s distributed evenly over space but a better way is to assume that light emission follows Lambert’s cosine law; lambertian sources have the same brightness no matter at what angle you look at them even though their emission is not uniform. Let’s not get too drawn into the specifics here other than to say that the light intensity follows a cosine law with angle and LEDs are often approximated to lambertian emitters. So why break tradition? OK then we can now say that the peak intensity in the forward direction will be 7.1 W / π = 2.3 W / sr where sr stands for steradian (a unit of angle in 3D space. Imagine the surface of a sphere rather than the arc of a circle).
  • To get the power on the front surface of our solar cell then, we just need to know how many steradians it covers and multiply.  For a 2mm x 2mm (0.04 cm2) solar cell positioned 2 cm away from the LED (face on), I expect it to cover approximately 0.031 sr (using the formula for a cone with spherical cap) which would give us 71.3 mW incident flux and an intensity of 1781 mW / cm2 or 18 Suns! At a more reasonable distance of 5 cm, we would still have 3 Suns which would be plenty.

I’ve included the details of all these calculations in this sheet.

Mounting

When I mounted the LED, I was concerned about applying enough pressure to ensure a strong bond and good thermal contact. Here, they recommend pressures in excess of 100psi! I managed only 8psi. Basically, I was concerned about breaking the LED board. I had to rest a power supply on top of a toothpick box – it seemed to be just the right size to clear the LED optical surface which shouldn’t be touched. Everything was a bit unstable as you can see…

Mounting the LED onto a CPU heatsink/fan with thermal adhesive film. Pressure applied using a small open box with a power supply on top giving 8psi.
Testing out the high power LED at 34V. Note that my power supply could only deliver 31V so I had to wire a couple of C (1.5V) batteries in series with it to get up to a more suitable voltage. You can see the meter is reading a current of 0.223A rather than the recommended 0.5A.

Driving circuit

I wired up a constant current LED driver to drive the LED with a potentiometer to control brightness (see schematics below). You can see from the chart that the output scales linearly with the voltage input to the dimmer pin – at 0V, you get the maximum output and at 4.2-4.3V the output has dropped right down to 0%.

The layout of the LED driver circuit based on the RECOM constant current LED driver unit. Output power can be controlled using the potentiometer which varies voltage supplied to the dimmer input. The output current as a function of the dimmer control voltage is also shown.

This appeared to work well when I tested it out. It got fairly bright as I adjusted the dimmer voltage which you can see from the image above however, I don’t have a way of actually measuring this at present. What I need is a calibrated meter. Unfortunately, this is outside the price range of the shed right now but I intend to do this when I visit the labs in Sheffield again.

Mismatch factor

An important figure of merit when it comes to benchmarking solar simulators is the concept of mismatch factor. It’s basically a score that your light source gets on how well it represents the solar spectrum. To work it out, we need to sum up the power in wavelength intervals over the visible and near infra-red portions of the electromagnetic spectrum for the sun (reference) and simulator (LED). Have a look at this figure below…

Calculating spectral mismatch factor: LED vs solar spectrum. Upper panel: relative spectral irradiance (area normalised) for the sun (red line) and our LED (black line). Lower panel: a table of integrated intensity over specified wavelength interval with mismatch factor (rightmost column).

Hopefully, you can see straight away that there’s a big difference in the shape of the two spectra. They have been area normalised – remember that the area under the spectra is the total power from the two sources. If we divide by area under the entire spectrum, then we’re effectively setting them to the same power for comparison which is what you would do when testing a solar cell. To get the mismatch, we then sum up the areas under the spectra between the intervals shown and compare (see table). You can see that the LED has a lot of its output in the visible range (400-700 nm) and none in the NIR compared to the sun.

To qualify as a class A solar simulator, the ratio (last column in the table) of all ranges needs to stay within 0.75 – 1.25 – we’re way off! Unfortunately, for this LED, the ratio even goes outside the allowed limits for class C (0.4 – 2.0). We need some NIR component to the spectrum to fix this which is possible. For the purposes of lifetime testing on a  budget however, then I think we need to accept these limitations. It’s good to know what they are though.

How long do solar cells live? (Part 2)

Circuit design

In this post, I want to talk about the circuit that I developed to drive solar cells at their maximum power point – the main building block of a modular lifetime tester. At this point, I should credit Sarah Sofia at MIT for her article “Build Your Own Sourcemeter“. This is what really gave me the inspiration and got me thinking that this would actually be possible with an Arduino and simple electronics.

Circuit layout of the prototype lifetime tester composed of DAC, op-amp and ADC interfaced by SPI with an Arduino UNO. The Arduino is interfaced with a PC through the serial port. Note that only one channel is shown here (one DUT).

A schematic of the lifetime tester circuit is shown above. In essence, the system is composed of:

  • a two-channel DAC (MCP4822) to give me the drive voltage across the solar cell. Because there are two channels I can run two solar cells at the same time. Typically, several subcells (6-8) are made on the same substrate so here, we can test two subcells of the same device at the same.
  • solar cell output is dumped into separate small (10-100 Ohm) series resistors which allow us to measure the current from the voltage dropped across them (applying Ohm’s law). Since resistance values and currents are small, the voltage drop will be small (we don’t want to drop much voltage in our ammeter).
  • an opamp is then needed to (on each channel) to bring the voltage to something that an ADC (ADS1286) can actually read. In fact, I’ve used an inverting op-amp with variable gain up to 1000x. To account for the fact that different solar cells under test might have different efficiencies and could therefore supply a different current, the gain is variable.

In this circuit, only the fourth quadrant (power generating region of the IV characteristic) can be accessed. Under operation, a solar cell will supply a current in the opposite direction to the applied bias. This means that the voltage across the series resistor will, in fact, be negative – one terminal is grounded, the other will be at some voltage below 0V. This signal gets fed into an inverting opamp which flips it positive again and amplifies it too. Any positive voltage at the input here will be rejected as it will be inverted to a negative output and will hit the 0V supply rail of the opamp. This means that if you try to run the solar cell in forward bias above the open-circuit voltage, giving you a forward current, you won’t get any output from the amplifier. I’ve tried to give you an illustration of this in the figure below (see lower panel).

(upper panel) LT spice model used to simulate and design the lifetime tester circuit. Note that the solar cell (DUT) has been modelled as a diode, current source and some resistors. (Lower panel) simulated input voltage from the DUT (blue line) and output (red line) voltage from the op-amp.

So did it work?…

To answer this, I connected up a solar cell and just went for a simple voltage sweep from the DAC while monitoring the current using the ADC. Here’s what the data looked like…

Using the prototype lifetime tester circuit to measure an I-V characteristic from a perovskite solar cell under illumination (black line). Power output (red line) has been calculated from DAC binary value * ADC binary value.

I was pretty happy when I saw this data. As you can see, it looks almost exactly how we expected it to from simulations and from understanding how an inverting op amp should operate. Furthermore, the fact that we can get power output curve and see a clear maximum power point (MPP) means things are looking good for doing MPP tracking. There’s some noise but I think this might have been from the fact that I was using the torch on my phone as an illumination source and it was hard to hold it exactly still. Since the measurement takes several seconds to complete, shaky hands could well be the culprit.

If you’re interested in how I coded this, then please follow the link.

…now for the digital-to-analogue converter

Now I’m dealing with the mirror case to the ADC that I just posted on. Instead of us reading an analogue voltage and converting that to a digital representation, we want an analogue voltage from a digital signal (DAC). In other words, I want the Arduino to give me a voltage from an int. But this is just like the AnalogWrite() function right?… Wrong!

  1. AnalogWrite()  does not give us an analogue voltage. It gives us a pulse width modulated (PWM) digital signal ie. the output is either 0 or 5V and we change the ratio of on and off time to give us an analogue-like signal for driving motors for example. This is not truly analogue in that what we want is to be able to select any DC  voltage between 0 and 5V that we want. We could apply a filter to the PWM signal to convert it to DC and this would be a cheap and fast trick but we would lose speed and voltage.  Speed is a key figure of merit in a digital-to-analogue converter (DAC) systems as it determines the sampling rate.
  2. Resolution – if we were to go with option 1 plus filter, with the Arduino, we’re limited to a resolution of 8 bits ie. the output voltage would be scaled between 0-255*Vout. On the other hand with an external DAC, we could choose our resolution up to 32 bits ie. 0-4294967296!
The circuit schematic that I used to test out the MCP4822 DAC. Note that I used a digital voltmeter connected to pin 8 (Va output) to monitor the output and I sent commands over SPI using an Arduino UNO.

So being able to use a DAC is going to be an important tool in our kit for attacking lots of projects. These things are commonplace in A/V equipment and mobile phones but I have another project in mind for this. More on that later. First, let’s discuss how to use a DAC – in this case the 12bit MCP4822. Se pinout here…

Pinout diagram for the MCP4822 DAC

If you’ve not done so already, have a look back at my previous post on using an ADC which covers the basics of SPI connections, bit math and relevant code.

Same as before, we’re going to setup an SPI connection between the DAC and Arduino but this time we transfer data over the master-out-slave-in (MOSI) line. The process will look like this:

  1. Setup the SPI interface first given the settings in the chip datasheet.
  2. Take user input from the serial connection and store it as text.
  3. Separate the channel address, voltage and gain from the users command and store as char, int and int respectively.
  4. Convert our int representation of voltage to two binary bytes.
  5. Change the state of some of the leading bits to denote which channel of the DAC we’re addressing (A or B) and what gain we would like (1 or 2).
  6. Take the CS pin LOW and transfer two bytes via SPI (MSB first). Then return the CS pin to HIGH again.
  7. Print the result to the serial window.
  8. Repeat
SPI communication protocol for the MCP4822 DAC.

Above you can see an extract from the datasheet that illustrates the SPI protocol. So how do we actually set the voltage that we want? Well, the MCP4822 has two channels, two gain settings and a 12-bit DAC register meaning and the voltage is calculated as follows…

Vout = Gain*Vref*(D/4095)

…where the gain is either 1 or 2, Vref=2.04V and is the internal voltage reference of the DAC, and D is the binary input that we send to the unit over SPI. Having an internal reference voltage means that even though the supply voltage may change slightly, the output is going to be stable since Vref is a stabilised internal reference…Nice! So this means we can choose whether we want to scale our voltage over 0.00-2.04V or 0.00-4.08V by the gain setting, either large/small range low/high resolution depending on our application, by using the gain setting.

Here is an extract from the MCP4822 datasheet for further information. It shows how the output is calculated and the writing process with example input. You can see that the before our binary input (left of the most significant bit) there are some extra bits referred to as config bits which in my code are inside the most significant byte (named MSB in the following code). We need to concentrate on bit 15, the channel selector, bit 13, the gain selector and bit 12, the shutdown bit…

 

Extract from the MCP4822 datasheet showing the write command register. I’ve also given you an example of the kind of thing you would send to the unit and what that actually means.

Now let’s discuss how the code could look. The basic process is given in the numbered list above but let’s elaborate here (You’ll find a complete copy of the code at the bottom of the post):

Setup the SPI interface

  // set the CS as an output:
  pinMode (DAC_CS, OUTPUT);
  Serial.begin(9600);     // opens serial port, sets data rate to 9600 bps
  inputString.reserve(200); // reserve 200 bytes for the inputString:
  SPI.begin();

Take user input from the serial connection

  // read the incoming string:
  inputString = Serial.readString();
  // say what you got:
  Serial.print("I received: ");
  Serial.println(inputString);

Separate the channel address, voltage and gain from the user’s command and store as char, int and char respectively

//extract channel address
  channel = inputString.charAt(0);
  //and gain
  gain = inputString.charAt(1);
  //convert string to an int - binary voltage
  n = inputString.substring(2).toInt();
  //set DAC state
  DAC_set(n, channel, gain, DAC_CS, errmsg);
  //print errors if there are any
  Serial.println(errmsg);

  //clear input string ready for the next command
  inputString = "";

Convert our int representation of voltage to two binary bytes

  //convert decimal input to binary stored in two bytes
  MSB = (input >> 8) & 0xFF;  //most sig byte
  LSB = input & 0xFF;         //least sig byte

Set the config bits

You will see that setting config bits is done with bit manipulation. In essence, if you want to set bit 7 to a 1, you need to do an OR operation on your data with 10000000 (which is 0x80 in hex) – this is useful in setting the channel bit. If instead, you want to set the same bit to 0, you would do an AND operation with 01111111 (0x7F) so you would end up setting bit 7 to 0 and keeping any data that you already had. If you did, AND 00000000, all your bits would go to 0 of course.

 //apply config bits to the front of MSB
  if (DAC_sel=='a' || DAC_sel=='A')
    MSB &= 0x7F; //writing a 0 to bit 7.
  else if (DAC_sel=='b' || DAC_sel=='B')
    MSB |= 0x80; //writing a 1 to bit 7.
  else
    errmsg += "DAC selection out of range. input A or B.";

  if (Gain_sel=='l' || Gain_sel=='L')
    MSB |= 0x20;
  else if (Gain_sel=='h' || Gain_sel=='H')
    MSB &= 0x1F;
  else
    errmsg += "Gain selection out of range. input H or L.";

  //get out of shutdown mode to active state
  MSB |= 0x10;

Take the CS pin LOW and transfer two bytes via SPI (MSB first). Then return the CS pin to HIGH again.

  //now write to DAC
  // take the CS pin low to select the chip:
  digitalWrite(CS_pin,LOW);
  delay(10);
  //  send in the address and value via SPI:
  SPI.transfer(MSB);
  SPI.transfer(LSB);
  delay(10);
  // take the CS pin high to de-select the chip:
  digitalWrite(CS_pin,HIGH);

Print the result to the serial window.

  Serial.println("binary input to DAC: ");
  Serial.print(MSB,BIN);
  Serial.print(" ");
  Serial.println(LSB,BIN);

Repeat

In the serial monitor, you should see something like this…

I received: AL500

binary input to DAC: 
110001 11110100

I received: AL0

binary input to DAC: 
110000 0

I received: al1000

binary input to DAC: 
110011 11101000

I received: al0

binary input to DAC: 
110000 0

I received: AL1000

binary input to DAC: 
110011 11101000

You get the command back that you wrote in then the binary input to the DAC and any errors.  To check that the code and hardware were working, I measured the output from the DAC as a function of binary input. Here is what I got…

What follows is the final code that I used to check my DAC. It contains separate functions for setting the state of the DAC and reading user input from the Arduino Serial monitor. I hope this post is enough to give you the basics of DAC implementation using an Arduino. If you have any questions, please comment and I’ll do my best to answer. Note that this code is limited in terms of speed. I’ve included some short (10ms) delays in the code which would really slow the application of the DAC if we wanted to sample at high data rates. One to return to at a later date.

/*
D. Mohamad 29/03/17 code to commumincate with MCP4822 12-bit DAC via SPI
pin assignments as follows...
      Uno (master)  MCP4822 (slave)
CS    8             2
MOSI  11            4
SCK   13            3
Read output voltage with a multimeter Va/Vb on pin 8/6.
send commands via serial interface eg.
AL1000 would mean...
channel=A
gain=low
D=1000
Va = gain*Vref*D/4095
= 1*2.04*1000/4095 = 0.498V
see www.theonlineshed.com
 */


#include <SPI.h>

const int DAC_CS = 8; //Chip select pin for the DAC
String inputString = ""; //holds serial commands

void setup() {
  // set the CS as an output:
  pinMode (DAC_CS, OUTPUT);
  Serial.begin(9600);     // opens serial port, sets data rate to 9600 bps
  inputString.reserve(200); // reserve 200 bytes for the inputString:
  SPI.begin();
}

//function to set state of DAC - input value between 0-4095
void DAC_set(unsigned int input, char DAC_sel, char Gain_sel, int CS_pin, String &errmsg)
{
  //DAC_sel choose which DAC channel you want to write to A or B
  //Gain_sel choose your gain: H=2xVref and L=1xVref
  byte MSB,LSB;//most sig, least sig bytes and config info

  //clear error messages
  errmsg="";

  Serial.flush();  // in case of garbage serial data, flush the buffer
  delay(10);

  //only run the rest of the code if binary is in range.
  if (input<0 || input >4095)
    errmsg += "input out of range. 0-4095.";
  else
  {
  //convert decimal input to binary stored in two bytes
  MSB = (input >> 8) & 0xFF;  //most sig byte
  LSB = input & 0xFF;         //least sig byte
  
  //apply config bits to the front of MSB
  if (DAC_sel=='a' || DAC_sel=='A')
    MSB &= 0x7F; //writing a 0 to bit 7.
  else if (DAC_sel=='b' || DAC_sel=='B')
    MSB |= 0x80; //writing a 1 to bit 7.
  else
    errmsg += "DAC selection out of range. input A or B.";

  if (Gain_sel=='l' || Gain_sel=='L')
    MSB |= 0x20;
  else if (Gain_sel=='h' || Gain_sel=='H')
    MSB &= 0x1F;
  else
    errmsg += "Gain selection out of range. input H or L.";

  //get out of shutdown mode to active state
  MSB |= 0x10;

  Serial.println("binary input to DAC: ");
  Serial.print(MSB,BIN);
  Serial.print(" ");
  Serial.println(LSB,BIN);

  //now write to DAC
  // take the CS pin low to select the chip:
  digitalWrite(CS_pin,LOW);
  delay(10);
  //  send in the address and value via SPI:
  SPI.transfer(MSB);
  SPI.transfer(LSB);
  delay(10);
  // take the CS pin high to de-select the chip:
  digitalWrite(CS_pin,HIGH);
  }
}

//function to read user command from the serial command window and set the DAC output
void serial_DAC_set(void)
{
  unsigned int n; //number 2 bytes long unsigned
  char channel, gain;
  String errmsg;  //errors returned from DAC_set
  
  // read the incoming string:
  inputString = Serial.readString();
  // say what you got:
  Serial.print("I received: ");
  Serial.println(inputString);
  
  //extract channel address
  channel = inputString.charAt(0);
  //and gain
  gain = inputString.charAt(1);
  //convert string to an int - binary voltage
  n = inputString.substring(2).toInt();
  //set DAC state
  DAC_set(n, channel, gain, DAC_CS, errmsg);
  //print errors if there are any
  Serial.println(errmsg);

  //clear input string ready for the next command
  inputString = "";
}

void loop()
{
  //only run when data is available
  if (Serial.available() > 0)
    serial_DAC_set();
}

My guide on using an analogue-to-digital converter

In this example, I’ve wired up an Analogue-to-digital converter (ADC) and showed you some code that will get this device talking to an Arduino using the SPI connection. There’s a potentiometer here that you can use to change the input voltage and it’s read once per second. Note that ADCs are capable of reading at much higher rates than this – according to the data sheet, the ADS1286 can sample at up to 20kHz but higher rates are possible.

ADC (ADS1286) circuit diagram. Device connected to Arduino Uno board with communication provided via SPI.

SPI stands for Serial Peripheral Interface and is a really impressive invention that allows ICs to talk to one another over short distances (on a PCB) using three wires: (1) clock, (2) master-out-slave-in (MOSI)/master-in-slave-out (MISO) and (3) chip select. In our case, since we’re dealing with receiving data from the slave (ADC), then we only use the MISO line. Wikipedia and Arduino have really good entries explaining this. However, I think that the timing diagram on Wikipedia is really helpful. Basically, when we want to talk to a chip over SPI, we send the chip select pin low, then send/read data over the MOSI/MISO data line. The whole thing is synchronised by clock pulses on the clock line. Each time the clock switches state, we end up reading another bit. The exact protocol of whether we (a) read bits on a low-high or high-low clock pulse and (b) whether bits are read on the leading or trailing edge of the clock is set in the SPI settings in the code (see below). Here is the exact operating sequence from the datasheet:

ADS1286 operating sequence straight from the datasheet. It’s not clear from this diagram but the clock polarity is 0 ie. it’s normally low and data bits are read on the trailing edge of the clock pulse. We read two bytes of data here and the most significant byte (MSB) comes out first.

In the code below, you can see that the process goes like this:

  1. Setup the SPI interface first given the settings discussed above and also set the clock speed as recommended by the manufacturers (It doesn’t seem to work if I don’t set this manually).
  2. Take the CS pin LOW and read out two bytes via SPI (MSB first). Then return the CS pin to HIGH again.
  3. Do some bit maths on these two bytes to convert them into a usable binary number.
  4. Cast this binary number into an int.
  5. Print the result to the serial window.
  6. Repeat.

Here’s some example raw data that we might read from the unit. The whole thing looks like this…

Format of data read from the ADC. Note that we read 16 bits but only 12 of them are actually useful. What follows in the code is an effort to shift things around and get rid of the junk bits in steps (1) to (4).

So what we need to do is keep only the data inside the box and get rid of everthing else. The key line in the code is this one…

ADCval = ((MSB & 0x3e)<<8 | LSB) >> 1;

Notice that we do a bitwise AND first with the MSB and 0x3e which is hex for 00011111 (step 1). This effectively does an AND operation with each bit in the MSB  and this number. Therefore anything in the first three bits gets switched to a 0 because any bit AND 0 -> 0. Then we shift the MSB left 8 places (step 2) and do a bitwise OR with the LSB (step 3). This effectively moves the MSB into its correct position as the most significant data and stuffs the LSB onto the end. Lastly, we shift everything right one place to get rid of the junk hanging off the end (step 4). This effectively shifts it off the end. Note that this will only work because we have declared ADCval as an unsigned int. If not, instead of a 0 being moved in from the left as we shift everything right, a 1 would end up there instead.

And here’s the rest of the code which includes the steps for addressing the ADC.

#include <SPI.h>
//pin connections
//Arduino       ADC
//12 MISO       6 (with 10k pull-up)
//10 CS         5
//13 SCK        7
const int CS = 8;

void setup() {
  // set the CS as an output:
  pinMode (CS, OUTPUT);
  Serial.begin(9600);     // opens serial port, sets data rate to 9600 bps
  
  SPI.begin();
  SPI.beginTransaction(SPISettings(20000, MSBFIRST, SPI_MODE0));
}

//function to read state of ADC
int ADCread(void)
{
  unsigned int ADCval=0;
  byte MSB,LSB;

  //now write to DAC
  // take the CS pin low to select the chip:
  digitalWrite(CS,LOW);
  delay(10);
  //  send in the address and value via SPI:
  
  MSB = SPI.transfer(0x00); //most sig byte
  LSB = SPI.transfer(0x00); //least sig byte

  //print out the raw measurement
  for (int i=7;i>=0;i--)
    Serial.print(bitRead(MSB,i));   
  for (int i=7;i>=0;i--)
    Serial.print(bitRead(LSB,i));
  Serial.println();

  //now get rid of the first three digits (most sig bits)
  //combine with the LSB
  //shift everything right one to get rid of junk least sig bit
  ADCval = ((MSB & 0x3e)<<8 | LSB) >> 1;

  //print out data again
  for (int i=15;i>=0;i--)
  Serial.print(bitRead(ADCval,i));
  Serial.println();
  
  delay(10);
  // take the CS pin high to de-select the chip:
  digitalWrite(CS,HIGH);

  return(ADCval);
}

void loop()
{
  int data = ADCread();
  Serial.println(data);
  delay(1000);
}

Here’s an example of the kind of thing that you get on the serial monitor…

1100110110101101
0000011001010110
1622
1100110110101010
0000011001010101
1621
1100110110101101
0000011001010110
1622
1100110110101101
0000011001010110
1622
1100110110101111
0000011001010111
1623
1100110110100111
0000011001010011
1619
1100011111001010
0000001101100101
869
1100010011110000
0000001001111000
632
1100000100101000
0000000000010100
20
1100000000000000
0000000000000000
0
1100000000000000
0000000000000000
0

…first, you get the raw data read from the ADC followed by the shifted bits after we do our maths. Then you get the decimal value representing the voltage which is Vin/Vref*4095.

I decided it might be a good idea to check the linearity of the device. I wanted to be able to relate the binary output from the ADC to a real voltage. Testing this is pretty easy.  I monitored the wiper terminal (ADC input) using a digital voltmeter and compared it to the ADC output from the serial window. Here is what I got…

As you can see, everything looks rosy. The response is linear to a high degree of accuracy and the gradient is 812 V^-1 = 4095 binary / 5.042V. I hope this post will help explain the basic process of how to implement an ADC. Get in touch if I’ve missed anything.